Hodgkin-Huxley equations: Simulating action potential generation

See: http://physics.uwa.edu.au/pub/Biophysics/Assignments/Action.nb

For a java demo see: http://www.afodor.net/HHModel.htm

The equivalent circuit diagram

Voltage between inside (top of figure) and outside (bottom of figure) of the neuron membrane

The equations make use of Ohm's, Kirchoff's and Faraday's laws, and involve activation coefficients for the sodium (m), potassium (n) and an inactivation coefficient for Sodium (h). m, h & the experimentally estimated rate constants determine the sodium conductance. Similarly for the n and the potassium conductance.

Conductances g are equal to 1/R.

Voltage-dependent rate constants

Empirically determined.

(Subscript[α, m])[v_]:=((0.1 (25-v))/(Exp[((25-v)/10)]-1));
(Subscript[α, n])[v_]:=((0.01 (10-v))/(Exp[((10-v)/10)]-1));
(Subscript[α, h])[v_]:=0.07 Exp[-(v/20)];
(Subscript[β, m])[v_]:=4 Exp[-(v/18)];
(Subscript[β, n])[v_]:=0.125 Exp[-(v/80)];
(Subscript[β, h])[v_]:=(1/(Exp[((30-v)/10)]+1))
(Subscript[(i_), ∞])[v_]:=(((Subscript[α, i])[v])/((Subscript[α, i])[v]+(Subscript[β, i])[v]))

Constants

Constant	Units	Value
Cm	μF cm-2	1.0
ER	mV	-75.0
ENa	mV	ER + 115.0
EK	mV	ER - 12.0
EL	mV	ER + 10.613
gNa,max	mS cm-2	120.0
gK,max	mS cm-2	36.0
gL	mS cm-2	0.3

The parameter values below are in the units: mS/(cm^2), μF/(cm^2), mV:

(Subscript[(OverBar[g]), Na])=120.0;
(Subscript[(OverBar[g]), K])=36.0;
(Subscript[g, leak])=0.3;
𝒞=1;
(Subscript[ℰ, Na])=115;
(Subscript[ℰ, K])=-12;
(Subscript[ℰ, leak])=10.6;

Setting up the equations

Time is in msec.

(Subscript[g, Na])[t_]=(Subscript[(OverBar[g]), Na])((m[t])^3)h[t];
(Subscript[g, K])[t_]=(Subscript[(OverBar[g]), K])((n[t])^4);

HHequations:={
		m'[t]==(Subscript[α, m])[v[t]] (1-m[t])-(Subscript[β, m])[v[t]] m[t],
		n'[t]==(Subscript[α, n])[v[t]] (1-n[t])-(Subscript[β, n ])[v[t]] n[t],
		h'[t]==(Subscript[α, h])[v[t]] (1-h[t])-(Subscript[β, h])[v[t]] h[t],𝒞 v'[t]+(Subscript[g, Na])[t](v[t]-(Subscript[ℰ, Na]))+(Subscript[g, K])[t](v[t]-(Subscript[ℰ, K]))+(Subscript[g, leak])(v[t]-(Subscript[ℰ, leak]))==i[t]};

initialvalues={v[0]==0,m[0]==(Subscript[m, ∞])[0],n[0]==(Subscript[n, ∞])[0],h[0]==(Subscript[h, ∞])[0]};

Simulating the response to a pair of depolarizing  current pulses with a peak current density of Imax μA/(cm^2), each lasting pulsewidth msec separated by delay msec.

Manipulate[Module[{},
i[t_]:=If[(t≥5&&t≤5+pulsewidth)||(t≥5+pulsewidth+delay&&t≤5+pulsewidth+delay+pulsewidth),Imax,0];solution=NDSolve[{HHequations,initialvalues},{v,m,n,h},{t,0,100}];
GraphicsGrid[{{Plot[i[t],{t,1,100},PlotRange->{0,20.}],
Plot[v[t]/.solution,{t,1,100},PlotRange->{-30,130}]}}]],{{Imax,10.},1.,20.},{{pulsewidth,5.},0.,50.},{{delay,10.},1.,80.}]

References

Hodgkin, A. L., & Huxley, A. F. (1952). A quantitative description of membrane current and its application to conduction and excitation in nerve. J. Physiol. (Lond.), 117, 500-544.

 http://physics.uwa.edu.au/pub/Biophysics/Assignments/Action.nb